Coded by Thammi
 thammi@knut-tempel.de

License: GPL


EINGABE

schrift vorbereiten mit einer 100
>+++++++++[<+++++++++>-]<+++++++++++++++++++>

obere grenze
+++++[>++<-]>+
[[>]->+[<]>-]
>[>]
einlesen
>,[
	zeichen runterrechnen
	<++++++[>--------<-]>-
	erkennen
	[<++>+[-]]<->
	platz lassen
	+>
	einlesen endet ohne linefeed!!!
	,[
		trennzeichen runterrechnen
		>++++++++[<------->-]<---
		erkennen
		die 2 im tmp noch entfernen bei bedarf
		[[+]->+>]
		eins weiter
		>
	],
]
ziel anheben
<<+>>
untere grenze
>+++++++++++
[[>]->+[<]>-]
<->+[<]

PFAD FINDEN

#>>>>>>>>>>>>>>>>>>>>>>
anwenden bis anfang erreicht
[
	>
	einzelne zeichen auswerten
	[
		SELBST checken
		>[-]<<[-]>
		+>-<<->[->+<<+>]
		>+<->[-<+>]+<<
		unangetastet
		+[
			wand
			--[[-]+
				LINKS schauen
				<<
				[-]<<[-]>>>
				+<-<<->>>[-<+<<+>>>]<<<
				+>>>-<<<[->>>+<<<]+>>
				wand
				+[-
					auf unangetastete addieren
					-[[-]>>-<<]>>[
						[-]>[-<+<+>>]<[->+<]
					]+<<
				[-]]+>>
				
				RECHTS schauen
				>>
				[-]>>[-]<
				+>-<<->[->+<<+>]>
				+<->[-<+>]+<<
				wand
				+[-
					auf unangetastete addieren
					-[[-]<<->>]<<[
						[-]>[-<+>>>+<<]<[->+<]
					]+>>
				[-]]+<<
				
				OBEN schauen
				[-]
				<<<<<<<<<<<<<<<<<<<<
				[-]>>[-]<
				+<->>-<[-<+>>+<]>
				+<->[-<+>]+<<
				+[-
					-[+[-]>>-<<]+>>[
						<<->>
						zurueck und vorbereiten
						[>]>>[-]<[->+<<+>]>[-<+>]<<
						rueberkopieren
						<<[[-]>>[-<<+>>]+<<<<]+
						adden
						>>[-<+>]+
						get back
						[>]+<<-<<
					[-]]
				]+
				zelle wiederfinden
				[>]+
				
				UNTEN schauen
				[-]
				>>>>>>>>>>>>>>>>>>>>>>
				[-]<<[-]>
				+<->>-<[-<+>>+<]<
				+>-<[->+<]+>>
				+[-
					-[+[-]<<->>]+<<[
						>>-<<
						zurueck und vorbereiten
						[<]>>[-]<[->+<<+>]<[->+<]>>
						rueberkopieren
						>>[[-]<<[->>+<<]+>>>>]+
						adden
						<<[->+<]+
						get back
						[<]>>-
					[-]]
				]+
				zelle wiederfinden
				[<]+
			[-]]
		]+>
		weiter gehts
		>>
	]
	zum anfang springen
	<[<]>>>>>>>>>>>>>>>>>>>>>>>
	ende feststellen
	-[+<<+>[-]]+<
]
->>

PFAD ABLAUFEN

#--[++
	RECHTS schauen
	>>
	<[-]>>[-]<
	+>-<<->[->+<<+>]<
	+>-<[->+<]+>>
	+[--[+
		<<[-]<<[-]>
		[->+<<+>]<[->+<]+>>
		vergleichen
		>>[-<<->>]+<<
		-[[+]>>-<<]+>>[
			zeichen ausgeben
			-<[<]<<[->+>+<<]>[-<+>]>
			++++++++++++++.[-]++++++++++.[-]
			>[>]+>>-
		]
	]]+
	<
	<<
	
	UNTEN schauen
	<[-]
	>>>>>>>>>>>>>>>>>>>>
	[-]>>[-]<
	+>-<<->[->+<<+>]<
	+>-<[->+<]+>>
	+[--[+
		ausgang ranholen
		<<-<[<]
		>>[-]<[-<+>>+<]<[->+<]>>
		>>[[-]<<[->>+<<]+>>>>]<<[->>+<<]+>>
		vergleichen
		>>[-<<->>]+<<
		-[[+]>>-<<]+>>[
			zeichen ausgeben
			-<[<]<[<]<<[->+>+<<]>[-<+>]>
			.[-]++++++++++.[-]
			>[>]>[>]
			alte marke killen
			<[<]+[>]<<->>
		]
	]]+
	[<]
	+>
	
	LINKS schauen
	<<
	>[-]<<[-]>
	+<->>-<[-<+>>+<]>
	+<->[-<+>]+<<
	+[--[+
		>>[-]>>[-]<
		[-<+>>+<]>[-<+>]+<<
		vergleichen
		<<[->>-<<]+>>
		-[[+]<<->>]+<<[
			zeichen ausgeben
			-<[<]<<[->+>+<<]>[-<+>]>
			++++++++.[-]++++++++++.[-]
			>[>]+<<-
		]
	]]+
	>
	>>
	
	OBEN schauen
	>[-]
	<<<<<<<<<<<<<<<<<<<<
	[-]<<[-]>
	+<->>-<[-<+>>+<]>
	+<->[-<+>]+<<
	+[--[+
		ausgang ranholen
		>>->[>]
		<<[-]>[->+<<+>]>[-<+>]<<
		<<[[-]>>[-<<+>>]+<<<<]>>[-<<+>>]+<<
		vergleichen
		<<[->>-<<]+>>
		-[[+]<<->>]+<<[
			zeichen ausgeben
			-<[<]<<[->+>+<<]>[-<+>]>
			+++++++++++++++++.[-]++++++++++.[-]
			>[>]
			alte marke killen
			>[>]+[<]>>-<<
		]
	]]+
	[>]
	+<
--]